<%
    Server.ScriptTimeout = 120
    bDontCount = False
    sPageTitle = "2eNetWorX - Summary"
    bAdminOnly = False
    lSubjectID = 0
    sTitleBar = "/dev :: <a href=""/dev/index.asp"">home</a> :: summary"
%>

<!--#include virtual="/dev/_header.asp"-->


<br>
<p class="smallheader">
    2eNetWorX/dev :: Site Summary
</p>

<% sub ShowTitle(sTitle) %>
<br>
<table border="0" cellspacing="1" cellpadding="2" width="100%" class="tb-section">
    <tr><td class="td-section-title" valign="middle">
        &nbsp;<%=sTitle%>
    </td></tr>
</table>
<%
end sub

function GetProjectName(iProjectID)
    select case iProjectID
        case 1 : sName = "2eNetWorX/dev"
        case 2 : sName = "TableEditoR"
        case 3 : sName = "MiniSurvey"
        case 4 : sName = "StatCounteX"
        case 5 : sName = "PowerTool"
        case 6 : sName = "TransWindoW"
        case 7 : sName = "TransIt"
        case 8 : sName = "SimpleChat"
        case 9 : sName = "FlashLCD"
        case 10 : sName = "GetFileFoldeR"
        case 11 : sName = "HiLiteR"
        case 12 : sName = "OpenForum"
    end select
    GetProjectName = sName
end function

sub ShowSiteInfo

    dtBegin = #11/13/2000 00:20#
    sOnline = "<strong>" & DateDiff("d", dtBegin, Now) -1 & "</strong> days, <strong>" & DateDiff("h", dtBegin, Now) mod 24 & "</strong> hours."
    
    iUpTime = CInt(DateDiff("h", application("ServerStart"), Now))
    iDays = iUpTime \ 24
    iHours = iUpTime mod 24
    if iDays > 0 then
        sUpTime = "<strong>" & iDays & "</strong> days, <strong>" & iHours & "</strong> hours."
    else
        sUpTime = "<strong>" & iHours & "</strong> hours."
    end if
    
    
    set cDB = new DBClass
    cDB.Open sConnStats
    
    sSQL = "SELECT SUM(Total) As Total FROM Hits"
    set rs = cDB.GetRS(sSQL)
    lPageViewsTotal = rs("Total")
    rs.close
    
    sSQL = "SELECT Total FROM Hits WHERE HitDate = #" & SQLDate(Date) & "#"
    set rs = cDB.GetRS(sSQL)
    if not rs.eof then lPageViewsToday = rs("Total") + 1
    rs.close

    destroy cDB
    
    set cDB = new DBClass
    
    cDB.Open sConnUsers
    
    sSQL = "SELECT COUNT(*) AS Total FROM Users"
    set rs = cDB.GetRS(sSQL)
    iMemberCount = rs("Total")
    rs.close
    
    destroy rs
    destroy cDB

    ShowTitle "Site Info"
    
%>
<table cellpadding="2" cellspacing="1" border="0" width="100%">
<tr><td><strong>Server Date - Time</strong></td><td><%=formatdatetime(date, 1) & " - " & formatdatetime(time, 0)%><br>
<tr><td><strong>Site is Online for</strong></td><td><%=sOnline%></td></tr>
<tr><td><strong>Server is Online for</strong></td><td><%=sUptime%> (since reset)</td></tr>
<tr><td><strong>Visitors (Application)</strong></td><td><strong><%=formatnumber(application("VisitorsToday"), 0)%></strong> today, <strong><%=formatnumber(application("Visitors"), 0)%></strong> (since reset)</td></tr>
<tr><td><strong>Page Views (Application)</strong></td><td><strong><%=formatnumber(application("PageViewsToday"), 0)%></strong> today, <strong><%=formatnumber(application("PageViews"), 0)%></strong> (since reset)</td></tr>
<tr><td><strong>Page Views (StatCounteX)</strong></td><td><strong><%=formatnumber(lPageViewsToday, 0)%></strong> today, <strong><%=formatnumber(lPageViewsTotal, 0)%></strong> total</td></tr>
<tr><td><strong>Registered Members</strong></td><td><strong><%=formatnumber(iMemberCount, 0)%></strong> members</td></tr>
</table>
<%
end sub

sub ShowUserUploads
    ShowTitle "Latest User Uploads"
    
    set cDB = new DBClass
    cDB.Open sConnUploads
    
    sSQL = "SELECT TOP 5 UploadID, ProjectID, FileName FROM Uploads ORDER BY UploadID DESC"
    set rs = cDB.GetRS(sSQL)
    
    response.write "<table cellpadding=""2"" cellspacing=""1"" border=""0"" width=""100%"">"        
    do while not rs.eof
        iUploadID = rs("UploadID")
        iProjectID = rs("ProjectID")
        sFileName = rs("FileName")
        
        sName = GetProjectName(iProjectID)

        response.write "<tr><td width=""80%""><a href=""/dev/projects/download.asp?pid=" & iProjectID & "&uid=" & iUploadID & """>" & sFileName & "</a></td><td width=""20%"">" & sName & "</td></tr>"
        
        rs.movenext
    loop    
    response.write "</table>"

    destroy rs
    destroy cDB
end sub

sub ShowOpenForumMessages

    ShowTitle "Latest OpenForum Messages"

    set cDBF = new DBClass
    
    cDBF.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
             "Persist Security Info=False;Data Source=" & _
             Server.MapPath("/data/forum.mdb")
    
    sSQL = "SELECT MsgID, ForumID, Title FROM Messages ORDER BY MsgID DESC"
    set rsF = cDBF.GetRS(sSQL)

    response.write "<table cellpadding=""2"" cellspacing=""1"" border=""0"" width=""100%"">"        

    do while not rsF.eof
        iRec = iRec + 1
        if iRec = 6 then exit do
        
        select case rsF("ForumID")
            case 1 : sURL = "/dev/projects/2enetworx.asp"
            case 2 : sURL = "/dev/projects/tableeditor.asp"
            case 3 : sURL = "/dev/projects/minisurvey.asp"
            case 4 : sURL = "/dev/projects/statcountex.asp"
            case 5 : sURL = "/dev/projects/powertool.asp"
            case 6 : sURL = "/dev/projects/transwindow.asp"
            case 7 : sURL = "/dev/projects/transit.asp"
            case 8 : sURL = "/dev/projects/simplechat.asp"
            case 9 : sURL = "/dev/projects/flashlcd.asp"
            case 10 : sURL = "/dev/projects/getfilefolder.asp"
            case 11 : sURL = "/dev/projects/hiliter.asp"
            case 12 : sURL = "/dev/projects/openforum.asp"
            case 13: sURL = "/dev/hakan.asp"
        end select
        sURL = sURL & "?ofact=1&ofmsgid=" & rsF("MsgID") & "&ofdisp=2#openforum"
        'response.write "<a href=""" & sURL & """>" & rsF("Title") & "</a>"
        sName = GetProjectName(rsF("ForumID"))
        response.write "<tr><td width=""80%""><a href=""" & sURL & """>" & rsF("Title") & "</a></td><td width=""20%"">" & sName & "</td></tr>"
        rsF.MoveNext
    loop
    response.write "</table>"
    destroy rsF
    destroy cDBF

end sub

sub ShowPagesViewed()
    ShowTitle "Last 3 Pages You Viewed"

    response.write "<table cellpadding=""2"" cellspacing=""1"" border=""0"" width=""100%"">"        
    for i = 0 to 2
        sPageName = session("PageViewed" & trim(i))
        if sPageName = "" then
            sPageName = "(none)"
        else
            sPageName = "<a href=""" & sPageName & """>" & sPageName & "</a>"
        end if
        response.write "<tr><td>" & (i+1) & ". " & sPageName & "</td></tr>"
    next
    response.write "</table>"
end sub

'-- Main Code Execution
    
ShowSiteInfo
ShowUserUploads
ShowOpenForumMessages
ShowPagesViewed

%>
<br><br>
<strong><a href="/dev/live/hiliter/summary.asp">View the source code</a> of this file.</strong><br><br>
You will need some extra code for application level pageview and visitor counts, and for "last 3 pages" trick.
Get the <a href="/dev/live/hiliter/global.asp">global.asa</a> source I'm using on this site, and add <a href="/dev/live/hiliter/_header.asp">this code</a> to your header file to get the stuff working.


<br><br>
<!--#include virtual="/dev/_footer.asp"-->

Processing time: 6,54 seconds.

Visit 2eNetWorX for more OpenSource VB and ASP Projects.